% The Computer Modern Math Italic family (by D. E. Knuth, 1979--1985)

font_coding_scheme:="TeX math italic";
mode_setup; font_setup;

input romanu;  % upper case (majuscules)
input itall;  % lower case (minuscules)
input greeku;  % upper case greek letters
input greekl;  % lower case Greek letters
input italms;  % special symbols for math italic
font_slant slant;  font_x_height x_height#;
font_quad 18u#+4letter_fit#;

slant:=mono_charic#:=0;  % the remaining characters will not be slanted
currenttransform:=identity yscaled aspect_ratio scaled granularity;
input olddig;  % oldstyle numerals
input romms;  % roman math specials

skewchar=oct"177"; skew#=.5u#;
save comma;
period=oct"72"; comma=oct"73"; slash=oct"75"; % non-ASCII positions
ligtable "h": skewchar kern -skew#;
ligtable oct"027":oct"034": comma kern -u#, period kern -u#, % $\nu:\tau:$
 "L":"g":"u":"v":"x": oct"013": oct"026": % $L:g:u:v:x:\alpha:\mu:$
 oct"035":oct"173": skewchar kern skew#; % $\upsilon:\imath:$
ligtable "U": comma kern-2u#, period kern-2u#, % $U:$
 slash kern-u#, skewchar kern skew#;
ligtable "K":oct"011": slash kern-u#, % $K:\it\Psi:$
 oct"016":"r": comma kern-u#, period kern-u#, % $\delta:r:$
 "D":"c":"e":"o":"s":"y":"z":oct"017": % $D:c:e:o:s:y:z:\epsilon:$
 oct"021":oct"023":oct"037": skewchar kern 2skew#; % $\eta:\iota:\chi:$
ligtable oct"007": slash kern-u#, % $\it\Upsilon:$
 comma kern-2u#, period kern-2u#, skewchar kern 2skew#;
ligtable oct"005":"H": slash kern-u#, % $\it\Pi:H:$
 comma kern-u#, period kern-u#, skewchar kern 2skew#;
ligtable "N":"X": slash kern -1.5u#, % $N:X:$
 "C":"T": slash kern -.5u#, comma kern -u#, period kern -u#, % $C:T:$
 "B":"E":"G":"O":"Q":"R":oct"174": % $B:E:G:O:Q:R:\jmath:$
 "l":"p":"q":"t":"w":oct"002":oct"004": % $l:p:q:t:w:\it\Theta:\Xi:$
 oct"006":oct"010":oct"012":oct"014": % $\it\Sigma:\Phi:\Omega:\beta:$
 oct"020":oct"022":oct"032":oct"036": % $\zeta:\theta:\rho:\phi:$
 oct"042":oct"043":oct"045": % $\varepsilon:\vartheta:\varrho:$
 oct"046":oct"047":oct"100": % $\varsigma:\varphi:\partial:$
 skewchar kern 3skew#;
ligtable "M":"S":"Z": slash kern-u#, % $M:S:Z:$
 comma kern-u#, period kern-u#, skewchar kern 3skew#;
ligtable oct"000":"F":"P": slash kern -u#, % $\it\Gamma:F:P:$
 comma kern-2u#, period kern-2u#, skewchar kern 3skew#;
ligtable "I":oct"030":oct"040":oct"140":oct"175": % $I:\xi:\psi:\ell:\wp:$
 skewchar kern 4skew#;
ligtable "A": skewchar kern 5skew#; % $A:$
ligtable "d": "Y" kern u#, "Z" kern-u#, "j" kern-2u#, "f" kern-3u#, % $d:$
 oct"001":oct"003": skewchar kern 6skew#; % $\it\Delta:\Lambda:$
ligtable "f": comma kern-u#, period kern-u#, skewchar kern 6skew#; % $f:$
ligtable "J": slash kern-u#, % $J:$
 comma kern-2u#, period kern-2u#, skewchar kern 6skew#;
ligtable "j":oct"033": comma kern -u#, period kern -u#; % $j:\sigma:$
ligtable "V":"W":"Y":comma kern-3u#, period kern-3u#, % $V:W:Y:$
 slash kern-2u#;
ligtable slash: oct"001" kern -u#, "A" kern -u#, "M" kern -u#, % $/:$
 "N" kern -u#, "Y" kern +u#, "Z" kern -u#;
bye.